Minecraft - Küfür engelleme

[Romitou]

Herkese selam sizlere küfür engelleme skriptini paylaşıcam.

on load:
    load yaml "plugins/Küfür/küfürler.yml" as "küfür"
    if yaml "küfür" is empty:
        set yaml value "prefix" from "küfür" to "&eSunucu »"
        set yaml list "Küfürler" from "küfür" to "KÜFÜR YAZINIZ" , "KÜFÜR YAZINIZ" , "KÜFÜR YAZINIZ" , "KÜFÜR YAZINIZ" and "çocuğu"
    save yaml "küfür"
    stop

on chat:
    log "%player%: %message%" to "sohbet.log"

on chat:
    if {küfür::%player%} is not set:
        set {_chat::*} to message split at " "
        set {_prefix} to yaml value "prefix" from "küfür"
        set {_küfürler::*} to yaml list "Küfürler" from "küfür"
        loop {_chat::*}:
            loop {_küfürler::*}:
                if loop-value-1 = loop-value-2:
                    cancel event
                    add 1 to {küfür::uyarıplayeriçin::%player%}
                    send "%{_prefix}% &7Küfür barındıran mesajlar yazmanız &cyasak ! &b(Uyarı &a%{küfür::uyarıplayeriçin::%player%}%&b)"
                    if {küfür::uyarıplayeriçin::%player%} is greater than or equal to 2:
                        delete {küfür::uyarıplayeriçin::%player%}
                        execute console command "/emute %player% 3m Otomatik mute"
                    stop

command /izinver [<offline player>]:
    permission: perm.küfür
    permission message: &cYeterli yetkiniz yok !
    trigger:
        set {_prefix} to yaml value "prefix" from "küfür"
        if arg 1 is set:
            if {küfür::%arg 1%} is not set:
                set {küfür::%arg 1%} to true
                send "%{_prefix}% &7Küfür etme izni &e%arg 1% &7için &aaçıldı."
                stop
            else if {küfür::%arg 1%} is set:
                delete {küfür::%arg 1%}
                send "%{_prefix}% &7Küfür etme izni &e%arg 1% &7için &ciptal &7edildi."
                stop
        else:
            send "%{_prefix}% &cBir oyuncu giriniz !"
            stop